home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 2002 November / SGI Freeware 2002 November - Disc 1.iso / dist / fw_exmh.idb / usr / freeware / lib / exmh-2.5 / ftoc.tcl.z / ftoc.tcl
Text File  |  2002-07-08  |  36KB  |  1,365 lines
  1. # 
  2. # ftoc.tcl
  3. #
  4. # Folder table of contents display.
  5. #
  6. # Copyright (c) 1993 Xerox Corporation.
  7. # Use and copying of this software and preparation of derivative works based
  8. # upon this software are permitted. Any distribution of this software or
  9. # derivative works must comply with all applicable United States export
  10. # control laws. This software is made available AS IS, and Xerox Corporation
  11. # makes no warranty about the software, its performance or its conformity to
  12. # any specification.
  13.  
  14. proc Ftoc_Init {} {
  15.     global ftoc
  16.     set ftoc(displayValid) 0        ;# 1 => pick results, not full scan
  17.     set ftoc(displayDirty) 0        ;# 1 => display differs from cache
  18.     set ftoc(mono) [expr {[winfo depth .] <= 4}]
  19.     # Parameters to the Next button
  20.     Preferences_Add "Scan Listing" \
  21. "These settings affect the behavior of Exmh as you move through the scan listing to view and mark messages.
  22. While the default for Auto Commit is OFF, I suggest you try it out.
  23. Messages are still temporarily marked, but the commit is done when you need it." {
  24.     {exwin(ftextLines)    ftextLines 15    {Scan listing lines}
  25. "Lines in the Scan listing window, which is
  26. also called Folder-Table-Of-Contents (FTOC)."}
  27.     {ftoc(implied) impliedDirection ON "Implied Direction"
  28. "If set, Exmh will remember your current direction,
  29. next or previous, and go that way after you mark a
  30. message for deletion or refiling."}
  31.     {ftoc(nextGuard) nextGuard OFF "Next Guard"
  32. "If set, Exmh will warn you that you are about to
  33. change folders when you hit Next.  This means you
  34. end up hitting Next twice to chain the to next
  35. folder with unseen messages."}
  36.     {ftoc(autoCommit) autoCommit OFF "Auto Commit"
  37. "If set, Exmh will invoke the Commit operation to
  38. commit deletions and refiles when it would otherwise
  39. just complain that such a commit is required."}
  40.     {ftoc(commitDialog) commitDialog ON "Commit Dialog"
  41. "If set, you get a confirmation dialog when exmh wants
  42. you to commit pending changes.  Otherwise you just
  43. get a warning message and have to hit the Commit button."}
  44.     {ftoc(autoPack) autoPack OFF "Auto Pack"
  45. "If set, Exmh will pack the folder every time a commit is performed."}
  46.     {ftoc(autoSort) autoSort OFF "Auto Sort"
  47. "If set, Exmh will sort the folder every time you change into it"}
  48.     {ftoc(autoSortType) autoSortType {CHOICE date subject sender custom} {Sorting criterion}
  49. "Sort by Date:/Subject:/From: or user-defined fields. Uses MH sortm command."}
  50.     {ftoc(autoSortCrit) autoSortCrit {-textfield keywords} {Custom criterion}
  51. "Custom parameters for sortm"}
  52.     {ftoc(showNew) ftocShowNew OFF "Show New Messages"
  53. "If set, Exmh will scroll the FTOC display to show
  54. new message that arrive because of an Inc."}
  55.     {ftoc(linkAdvance) advanceOnLink OFF "Advance after Link"
  56. "If set, Exmh will advance to the next message after a link."}
  57.     {ftoc(skipMarked) skipMarked ON "Next/Prev skip marked msgs"
  58. "If set, Next and Prev will skip over messages that have
  59. been marked for move or delete."}
  60.     {flist(cycleBack)    cycleBack ON    "Cycle back to first"
  61. "If there are no folders with unseen messages, then this
  62. option causes you to change to the first folder given by your
  63. Folder-Order MH profile entry."}
  64.     {ftoc(scanWidth) scanWidth 100 "Default scan width"
  65. "This value is passed as the -width argument to scan and in."}
  66.     {ftoc(scanSize) scanSize 100 "Default amount to scan"
  67. "Only the last N messages are scanned when you first enter a folder.
  68. The number is controlled by this setting."}
  69.     }
  70. }
  71. proc Ftoc_Reset { numMsgs msgid folder } {
  72.     global ftoc exwin
  73.     Exmh_Debug Ftoc_Reset $folder has $numMsgs msgs
  74.     set ftoc(numMsgs) $numMsgs        ;# num msgs in the scan listing
  75.     set ftoc(changed) 0            ;# Number of moves/deletes marked
  76.     set ftoc(lineset) {}        ;# set of selected messages
  77.     set ftoc(pickone) 1            ;# lineset is empty
  78.     set ftoc(folder) $folder        ;# Currently displayed folder
  79.     set ftoc(direction) next        ;# assumed next direction
  80.     set ftoc(softChange) [expr {! $ftoc(nextGuard)}]
  81.     set ftoc(lasthit) {}        ;# search anchor
  82.     if {$msgid == {}} {
  83.     set ftoc(curLine) {}        ;# current display line number
  84.     } else {
  85.     set ftoc(curLine) {}        ;# Set later in Msg_Change ?
  86.     }
  87. }
  88. proc Ftoc_Update { numMsgs folder } {
  89.     # Update size of message list after inc'ing into current folder
  90.     global ftoc
  91.     Exmh_Debug Ftoc_Update $folder has $numMsgs msgs
  92.     set ftoc(numMsgs) $numMsgs
  93. }
  94.  
  95. proc Ftoc_Bindings { w } {
  96.     # Bindings for the ftoc text widget
  97.  
  98.     # The TScroll binding to too general.
  99.     # We'll do our own scroll bindings here.
  100.     bindtags $w [list $w]
  101.  
  102.     # Button-1 starts selection range
  103.     bind $w <Button-1> {
  104.     FtocRangeStart [lindex [split [%W index current] .] 0]
  105.     Exmh_Focus
  106.     }
  107.     bind $w <Shift-Button-1> {
  108.     FtocRangeAdd [lindex [split [%W index current] .] 0]
  109.     Exmh_Focus
  110.     }
  111.     bind $w <B1-Motion> {
  112.     FtocRangeExtendXY %x %y
  113.     }
  114.     bind $w <Shift-B1-Motion> {
  115.     FtocRangeExtendXY %x %y
  116.     }
  117.     bind $w <Any-ButtonRelease-1> {
  118.     FtocRangeEnd [lindex [split [%W index current] .] 0] 0
  119.     }
  120.     bind $w <Shift-ButtonRelease-1> {
  121.     FtocRangeEnd [lindex [split [%W index current] .] 0] 1
  122.     }
  123.     bind $w <Button-3> {
  124.     set lineNumber [lindex [split [%W index current] .] 0]
  125.     Msg_Pick $lineNumber noshow
  126.     Exmh_Focus
  127.     }
  128.     bind $w <Double-Button-1> { }
  129.     bind $w <Triple-Button-1> { }
  130.  
  131.     bind $w <Button-2> {WidgetTextMark %W %y}
  132.     bind $w <B2-Motion> {WidgetTextDragto %W %y $exwin(scrollSpeed)}
  133.  
  134.     Drag_Attach $w FtocDragSelect Shift 3
  135. }
  136. proc FtocRangeStart { line } {
  137.     # For normal button-down "start a selection"
  138.     global ftoc
  139.     Ftoc_RangeUnHighlight
  140.     set ftoc(pickstart) $line
  141.     set ftoc(pickend) $line
  142.     set ftoc(pickstate) new
  143.     set ftoc(extend) 0
  144.     Ftoc_RangeHighlight $line $line
  145. }
  146. proc FtocRangeAdd { line } {
  147.     # For shift-select "add to selection"
  148.     global ftoc
  149.     set ftoc(pickstart) $line
  150.     set ftoc(pickend) $line
  151.     set ftoc(pickstate) invert
  152.     set ftoc(extend) 0
  153.     FtocRangeInvert $line $line
  154. }
  155. proc FtocRangeEnd { {line {}} {addcurrent 0} } {
  156.     # For end of button sweep
  157.     global ftoc exwin
  158.     catch {unset ftoc(extend)}
  159.     if ![info exists ftoc(pickend)] {
  160.     # Spurious button-release event
  161.     return
  162.     }
  163.     if {($line == $ftoc(pickstart)) && !$addcurrent} {
  164.     # regular button click optimization
  165.     unset ftoc(pickend)
  166.     Msg_Pick $line show
  167.     return
  168.     }
  169.     if {$line != {}} {
  170.     FtocRangeExtend $line
  171.     }
  172.     FtocPickRange $addcurrent
  173.     catch {unset ftoc(pickend)}
  174. }
  175. proc Ftoc_PickMsgs { ids addtosel } {
  176.     # For adding to the selection by message number
  177.     global ftoc
  178.     Exmh_Status "Marking [llength $ids] hits"
  179.     set lines {}
  180.     for {set L 0} {$L <= $ftoc(numMsgs)} {incr L} {
  181.     set ix [lsearch $ids [Ftoc_MsgNumber $L]]
  182.     if {$ix >= 0} {
  183.         lappend lines $L
  184.         set ids [lreplace $ids $ix $ix]
  185.         if {[string length $ids] == 0} {
  186.         break
  187.         }
  188.     }
  189.     }
  190.     Ftoc_LinesHighlight $lines
  191.     FtocPickRange $addtosel
  192. }
  193. proc FtocRangeExtendXY { x y } {
  194.     global ftoc exwin widgetText
  195.  
  196.     if ![info exists ftoc(extend)] {
  197.     return
  198.     }
  199.     set active $ftoc(extend)
  200.  
  201.     set h [winfo height $exwin(ftext)]
  202.     if {$y > $h} {
  203.     set ftoc(extend) [expr $y-$h]
  204.     } else {
  205.     if {$y < 0} {
  206.         set ftoc(extend) $y
  207.     } else {
  208.         set ftoc(extend) 0
  209.     }
  210.     }
  211.     
  212.     if {$ftoc(extend) == 0} {
  213.     FtocRangeExtend [lindex [split [$exwin(ftext) index @$x,$y] .] 0]
  214.     } else {
  215.     if {! $active} {
  216.         set ftoc(lastmark) [lindex [ split [$exwin(ftext) index @$x,$y] .] 0]
  217.         after $widgetText(selectDelay) [list FtocSelExtend]
  218.     }
  219.     }
  220. }
  221. proc FtocSelExtend {} {
  222.     global ftoc exwin widgetText
  223.     set w $exwin(ftext)
  224.     if {![info exists ftoc(extend)] ||
  225.     ($ftoc(extend) == 0)} {
  226.     return
  227.     }
  228.     catch {
  229.     set delta [expr {$ftoc(extend) / 16}]
  230.     if {$delta == 0} {
  231.         set delta [expr { ($ftoc(extend) < 0) ? -1 : 1 }]
  232.     }
  233.     set newmark [expr {$ftoc(lastmark) + $delta}]
  234.     FtocRangeExtend $newmark
  235.     set ftoc(lastmark) $newmark
  236.     $w yview -pickplace $newmark.0
  237.     after $widgetText(selectDelay) [list FtocSelExtend]
  238.     }
  239. }
  240. proc FtocRangeExtend { line } {
  241.     global ftoc
  242.     if ![info exists ftoc(pickend)] {
  243.     return
  244.     }
  245.     if {$line <= 0} {
  246.     set line 1
  247.     }
  248.     if {$line > $ftoc(numMsgs)} {
  249.     set line $ftoc(numMsgs)
  250.     }
  251.     if {$line == $ftoc(pickend)} {
  252.     # Invariant, previously defined selection is fine.
  253.     return
  254.     }
  255.     if {$line == 0} {
  256.     # no messages in folder
  257.     return
  258.     }
  259.     if {$ftoc(pickstate) != "invert"} {
  260.     if {$ftoc(pickstart) < $ftoc(pickend)} {
  261.         # Growing downward
  262.         if {$line > $ftoc(pickend)} {
  263.         Ftoc_RangeHighlight [expr $ftoc(pickend)+1] $line
  264.         } else {
  265.         if {$line < $ftoc(pickstart)} {
  266.             if {$ftoc(pickstart) != $ftoc(pickend)} {
  267.             # Change direction
  268.             FtocRangeClear [expr $ftoc(pickstart)+1] \
  269.                     $ftoc(pickend)
  270.             }
  271.             Ftoc_RangeHighlight [expr $ftoc(pickstart)-1] $line
  272.         } else {
  273.             # Shrink selection
  274.             FtocRangeClear [expr $line+1] $ftoc(pickend)
  275.         }
  276.         }
  277.     } else {
  278.         # Growing upward
  279.         if {$line < $ftoc(pickend)} {
  280.         Ftoc_RangeHighlight [expr $ftoc(pickend)-1] $line
  281.         } else {
  282.         if {$line > $ftoc(pickstart)} {
  283.             if {$ftoc(pickstart) != $ftoc(pickend)} {
  284.             # Change direction
  285.             FtocRangeClear [expr $ftoc(pickstart)-1] \
  286.                     $ftoc(pickend)
  287.             }
  288.             Ftoc_RangeHighlight [expr $ftoc(pickstart)+1] $line
  289.         } else {
  290.             # Shrink selection
  291.             FtocRangeClear [expr $line-1] $ftoc(pickend)
  292.         }
  293.         }
  294.     }
  295.     } else {
  296.     if {$ftoc(pickstart) < $ftoc(pickend)} {
  297.         # Growing downward
  298.         if {$line > $ftoc(pickend)} {
  299.         FtocRangeInvert [expr $ftoc(pickend)+1] $line
  300.         } else {
  301.         if {$line < $ftoc(pickstart)} {
  302.             if {$ftoc(pickstart) != $ftoc(pickend)} {
  303.             # Change direction
  304.             FtocRangeInvert [expr $ftoc(pickstart)+1] \
  305.                     $ftoc(pickend)
  306.             }
  307.             FtocRangeInvert [expr $ftoc(pickstart)-1] $line
  308.         } else {
  309.             # Shrink selection
  310.             FtocRangeInvert [expr $line+1] $ftoc(pickend)
  311.         }
  312.         }
  313.     } else {
  314.         # Growing upward
  315.         if {$line < $ftoc(pickend)} {
  316.         FtocRangeInvert [expr $ftoc(pickend)-1] $line
  317.         } else {
  318.         if {$line > $ftoc(pickstart)} {
  319.             if {$ftoc(pickstart) != $ftoc(pickend)} {
  320.             # Change direction
  321.             FtocRangeInvert [expr $ftoc(pickstart)-1] \
  322.                     $ftoc(pickend)
  323.             }
  324.             FtocRangeInvert [expr $ftoc(pickstart)+1] $line
  325.         } else {
  326.             # Shrink selection
  327.             FtocRangeInvert [expr $line-1] $ftoc(pickend)
  328.         }
  329.         }
  330.     }
  331.     }
  332.     set ftoc(pickend) $line
  333. }
  334. proc FtocRangeInvert { start end } {
  335.     global exwin
  336.     set win $exwin(ftext)
  337.     if {$start > $end} {
  338.     set tmp $start ; set start $end ; set end $tmp
  339.     }
  340.     for {set line $start} {$line <= $end} {incr line} {
  341.     catch {
  342.         set newtag range
  343.         set oldtag {}
  344.         set nuke 0
  345.         foreach tag [$win tag names $line.0] {
  346.         case $tag {
  347.             deleted { set newtag drange ; set oldtag $tag ; break; }
  348.             moved { set newtag mrange ; set oldtag $tag ; break; }
  349.             range { set newtag {} ; set oldtag $tag ; break; }
  350.             drange { set newtag deleted ; set oldtag $tag ;
  351.                 set nuke 1; break}
  352.             mrange { set newtag moved ; set oldtag $tag ;
  353.                 set nuke 1; break; }
  354.         }
  355.         }
  356.         if {$nuke} {
  357.         set ix [lsearch $ftoc(lineset) $line]
  358.         if {$ix >= 0} {
  359.             set ftoc(lineset) [lreplace $ftoc(lineset) $ix $ix]
  360.         }
  361.         }
  362.         if {$oldtag != {}} {
  363.         $win tag remove $oldtag $line.0 $line.end
  364.         }
  365.         if {$newtag != {}} {
  366.         $win tag add $newtag $line.0 $line.end
  367.         }
  368.     }
  369.     }
  370. }
  371. proc Ftoc_RangeHighlight { start end } {
  372.     global exwin
  373.     set win $exwin(ftext)
  374.     if {$start > $end} {
  375.     set tmp $start ; set start $end ; set end $tmp
  376.     }
  377.     for {set line $start} {$line <= $end} {incr line} {
  378.     set newtag range
  379.     foreach tag [$win tag names $line.0] {
  380.         case $tag {
  381.         {drange deleted} { set newtag drange ;  break; }
  382.         {mrange moved} { set newtag mrange ;  break; }
  383.         }
  384.     }
  385.     $win tag add $newtag $line.0 $line.end
  386.     }
  387. }
  388. proc Ftoc_LinesHighlight { lines } {
  389.     global exwin
  390.     set win $exwin(ftext)
  391.     if {$lines == {}} {
  392.     return
  393.     }
  394.     WidgetTextYview $exwin(ftext) -pickplace [lindex $lines 0].0
  395.     update idletasks
  396.     foreach line $lines {
  397.     set newtag range
  398.     foreach tag [$win tag names $line.0] {
  399.         case $tag {
  400.         {drange deleted} { set newtag drange ;  break; }
  401.         {mrange moved} { set newtag mrange ;  break; }
  402.         }
  403.     }
  404.     $win tag add $newtag $line.0 $line.end
  405.     }
  406. }
  407. proc FtocRangeClear { start end } {
  408.     global exwin
  409.     set win $exwin(ftext)
  410.     if {$start > $end} {
  411.     set tmp $start ; set start $end ; set end $tmp
  412.     }
  413.     for {set line $start} {$line <= $end} {incr line} {
  414.     catch {
  415.         set newtag {}
  416.         set oldtag range
  417.         foreach tag [$win tag names $line.0] {
  418.         case $tag {
  419.             drange { set newtag deleted ; set oldtag drange; break; }
  420.             mrange { set newtag moved ; set oldtag mrange; break; }
  421.             range { break }
  422.         }
  423.         }
  424.         $win tag remove $oldtag $line.0 $line.end
  425.         if {$newtag != {}} {
  426.         $win tag add $newtag $line.0 $line.end
  427.         }
  428.     }
  429.     }
  430. }
  431. proc Ftoc_RangeUnHighlight { } {
  432.     global exwin
  433.     set win $exwin(ftext)
  434.     foreach tag {range drange mrange} {
  435.     foreach range [FtocMakePairs [$win tag ranges $tag]] {
  436.         eval $win tag remove $tag $range
  437.         if {$tag == "drange"} {
  438.         eval $win tag add deleted $range
  439.         }
  440.         if {$tag == "mrange"} {
  441.         eval $win tag add moved $range
  442.         }
  443.     }
  444.     }
  445. }
  446.  
  447. # For user programming
  448. proc Ftoc_BindDouble { cmd } {
  449.     global exwin
  450.     bind $exwin(ftext) <Double-1> $cmd
  451. }
  452. proc Ftoc_BindRight { cmd } {
  453.     global exwin
  454.     bind $exwin(ftext) <3> $cmd
  455. }
  456.  
  457. proc Ftoc_FindMsg { msgid {line {}} } {
  458.     global ftoc
  459.     if {$line != {}} {
  460.     switch -glob -- $line {
  461.         first  {return 1}
  462.         last   {return $ftoc(numMsgs)}
  463.         [0-9]* {
  464.         if {$line > $ftoc(numMsgs)} {
  465.             return $ftoc(numMsgs)
  466.         } else {
  467.             return $line
  468.         }
  469.         }
  470.         default {return {}}
  471.     }
  472.     }
  473.     if {$msgid == {}} {
  474.     return {}
  475.     }
  476. #
  477. # Linear search for pick and thread FTOCs (pseudo-displays)
  478. #
  479.     if !$ftoc(displayValid) {
  480.         for {set L 1} {$L <= $ftoc(numMsgs)} {incr L} {
  481.             if {[Ftoc_MsgNumber $L] == $msgid} {
  482.                 return $L
  483.             }
  484.         }
  485.         return {}
  486.     }
  487.  
  488.     set min 1
  489.     set max $ftoc(numMsgs)    ;# Ignore trailing blank line
  490.     while (1) {
  491.     set m1 [Ftoc_MsgNumber $min]
  492.     if {$msgid == $m1} {
  493.         return $min
  494.     }
  495.     set m2 [Ftoc_MsgNumber $max]
  496.     if {$msgid == $m2} {
  497.         return $max
  498.     }
  499.     if {$msgid > $m2 || $msgid < $m1} {
  500.         Exmh_Status "Cannot find $msgid ($m1,$m2)" warn
  501.         return "" ;# new message not listed
  502.     }
  503.     if {$max == $min} {
  504.         return ""    ;# not found
  505.     }
  506.     set next [expr int(($max+$min)/2)]
  507.     set m3 [Ftoc_MsgNumber $next]
  508.     if {$m3 > $msgid} {
  509.         set max $next
  510.     } elseif {$min == $next} {
  511.         Exmh_Status "Cannot find $msgid" warn
  512.         return "" ;# new message not listed
  513.     } else {
  514.         set min $next
  515.     }
  516.     }
  517.     # not reached
  518. }
  519. proc Ftoc_MsgNumber { L } {
  520.     global exwin
  521.     if [catch {$exwin(ftext) get $L.0 $L.end} line] {
  522.     return ""
  523.     }
  524.     return [Ftoc_MsgNumberRaw $line]
  525. }
  526. proc Ftoc_MsgNumberRaw { line } {
  527.     if [regexp {( *)([0-9]+)} $line foo foo2 number] {
  528.     return $number
  529.     } else {
  530.     return ""
  531.     }
  532. }
  533. proc FtocPickRange { {addcurrent 0} } {
  534.     # Select a range of messages, or add to the current range
  535.     # Because of toggle/inverted selections, we pretty much
  536.     # have to recompute the select set from range tags
  537.     global exwin ftoc
  538.     set lineset {}
  539.     if {$ftoc(curLine) != {}} {
  540.     if {$addcurrent} {
  541.         Ftoc_RangeHighlight $ftoc(curLine) $ftoc(curLine)
  542.     }
  543.     Ftoc_ClearCurrent
  544.     Msg_ClearCurrent
  545.     set ftoc(curLine) {}
  546.     }
  547.     foreach range [concat \
  548.     [FtocMakePairs [$exwin(ftext) tag ranges range]] \
  549.     [FtocMakePairs [$exwin(ftext) tag ranges drange]] \
  550.     [FtocMakePairs [$exwin(ftext) tag ranges mrange]]] {
  551.     set mark1 [lindex $range 0]
  552.     set line [lindex [split $mark1 .] 0]
  553.     lappend lineset $line
  554.     }
  555.     if {$lineset == {}} {
  556.     return            ;# spurious <ButtonRelease-1> events
  557.     }
  558.     set ftoc(lineset) $lineset
  559.     set ftoc(pickone) 0
  560.     if {[llength $ftoc(lineset)] == 1} {
  561.     # This calls Msg_Change,
  562.     # which calls Ftoc_ClearCurrent, which sets pickone to 1,
  563.     # and calls Ftoc_Change, which sets curline
  564.     Msg_Pick [lindex $ftoc(lineset) 0] show
  565.     } else {
  566.     Buttons_Range    ;# Enable actions on ranges
  567.     }
  568. }
  569. proc Ftoc_PickSize {} {
  570.     global ftoc
  571.     set len [llength $ftoc(lineset)]
  572.     if {$len == 0} {
  573.     return [llength $ftoc(curLine)]
  574.     } else {
  575.     return $len
  576.     }
  577. }
  578. proc Ftoc_NewFtoc {} {
  579.     global ftoc
  580.     set ids {}
  581.     foreach l $ftoc(lineset) {
  582.     lappend ids [Ftoc_MsgNumber $l]
  583.     }
  584.     if {[llength $ids] <= 1} {
  585.     Exmh_Status "Select more than one message first" warn
  586.     return
  587.     }
  588.     if {[Ftoc_Changes "new ftoc"] == 0} {
  589.     Exmh_Status $ids
  590.     Scan_ProjectSelection $ids
  591.     }
  592. }
  593.  
  594. # Ftoc_ClearCurrent and Ftoc_Change are two parts of
  595. # dinking the ftoc display when advancing a message.
  596.  
  597. proc Ftoc_ClearCurrent {} {
  598.     # Clear display of current message
  599.     global ftoc exwin
  600.     set ftoc(pickone) 1
  601.     set ftoc(lineset) {}
  602.  
  603.     if {$ftoc(curLine) != {}} {
  604.     $exwin(ftext) tag remove current $ftoc(curLine).0 $ftoc(curLine).end
  605.     $exwin(ftext) tag remove currentBg $ftoc(curLine).0 $ftoc(curLine).end
  606.     Ftoc_RescanLine $ftoc(curLine)
  607.     }
  608.     return $ftoc(curLine)
  609. }
  610. proc Ftoc_Change { msgid line {show show} } {
  611.     global ftoc exwin
  612.     set ftoc(curLine) [Ftoc_FindMsg $msgid $line]
  613.     if {$ftoc(curLine) == {}} {
  614.     set ok 0
  615.     } else {
  616.     if {$show == "show"} {
  617.         $exwin(ftext) tag remove unseen $ftoc(curLine).0 $ftoc(curLine).end
  618.     }
  619.     Ftoc_RescanLine $ftoc(curLine) +
  620.     $exwin(ftext) tag add current $ftoc(curLine).0 $ftoc(curLine).end
  621.     $exwin(ftext) tag add currentBg $ftoc(curLine).0 $ftoc(curLine).end
  622.     set top [$exwin(ftext) index @0,4]
  623.     if [catch {expr {$top+1}}] {set top 0}    ;# trap 100.-1 format, iconic
  624.     if {$ftoc(curLine) == $top ||
  625.         $ftoc(curLine) == $top+$exwin(ftextLines)-1} {
  626.         WidgetTextYview $exwin(ftext) [expr $ftoc(curLine)-$exwin(ftextLines)/2].0
  627.     } else {
  628.         WidgetTextYview $exwin(ftext) -pickplace $ftoc(curLine).0
  629.     }
  630.     set ok 1
  631.     }
  632.     return $ok
  633. }
  634. proc Ftoc_ShowUnseen { folder } {
  635.     global exwin flist
  636.     set unseen [Flist_UnseenMsgs $folder]
  637.     if {[llength $unseen] > 0} {
  638.     set end [$exwin(ftext) index end]
  639.     set line [lindex [split $end .] 0]
  640.     set msgNum 0
  641.     for {} {$line > 0} {incr line -1} {
  642.         set msgNum [Ftoc_MsgNumber $line]
  643.         set i [lsearch $unseen $msgNum]
  644.         if {$i >= 0} {
  645.         $exwin(ftext) tag add unseen $line.0 $line.end
  646.         set unseen [lreplace $unseen $i $i]
  647.         if {[llength $unseen] == 0} {
  648.             return 1
  649.         }
  650.         }
  651.     }
  652.     # Repair bogus unseen sequences
  653.     # msgNum is the smallest message number, but it might not be
  654.     # the first message in the folder because of short scans
  655.     # Anything in the unseen sequence above msgNum is probably wrong
  656.     # and can result from races with the background process
  657.     foreach id $unseen {
  658.         if {$id > $msgNum} {
  659.         Flist_MsgSeen $id
  660.         }
  661.     }
  662.     } else {
  663.     Flist_SeenAll $folder    ;# clear highlighting
  664.     return 0
  665.     }
  666. }
  667. proc Ftoc_MarkSeen { ids } {
  668.     global exwin ftoc
  669.  
  670.     set ids [lsort -integer -decreasing $ids]
  671.     for {set L $ftoc(numMsgs)} {$L > 0} {incr L -1} {
  672.     set ix [lsearch $ids [Ftoc_MsgNumber $L]]
  673.     if {$ix >= 0} {
  674.         $exwin(ftext) tag remove unseen $L.0 $L.end
  675.         set ids [lreplace $ids $ix $ix]
  676.         if {[llength $ids] == 0} {
  677.         break
  678.         }
  679.     }
  680.     }
  681. }
  682. proc Ftoc_RescanLine { ix {plus none} } {
  683.     global exmh exwin ftoc
  684.     if [catch {
  685.     set text [$exwin(ftext) get ${ix}.0 ${ix}.end]
  686.     set ok 0
  687.     case $plus {
  688.         "none" {
  689.         # Replace + (current marker) with blank
  690.         set ok [regsub {^( *[0-9]+)(\+)} $text {\1 } newtext]
  691.         }
  692.         "+" {
  693.         # Stick a + after the number, if needed
  694.         if ![regexp {^( *)([0-9]+)(\+)} $text] {
  695.             set ok [regsub {^( *[0-9]+)( )} $text {\1+} newtext]
  696.         }
  697.         }
  698.         "dash" {
  699.         # Stick a - after the number, if needed
  700.         if ![regexp {^( *)([0-9]+).-} $text] {
  701.             set ok [regsub {^( *[0-9]+.)(.)} $text {\1-} newtext]
  702.         }
  703.         # Annotations result in writes to the directory.
  704.         # Here we mark the display dirty to force an update
  705.         # of the cache and prevent later rescans.
  706.         set ftoc(displayDirty) 1
  707.         }
  708.     }
  709.     if {$ok} {
  710.         set tags [$exwin(ftext) tag names ${ix}.0]
  711.         $exwin(ftext) configure -state normal
  712.         $exwin(ftext) delete ${ix}.0 ${ix}.end
  713.         $exwin(ftext) insert ${ix}.0 $newtext
  714.         $exwin(ftext) configure -state disabled
  715.         foreach tag $tags {
  716.         $exwin(ftext) tag add $tag ${ix}.0 ${ix}.end
  717.         }
  718.     }
  719.     } msg] {
  720.     Exmh_Error "FtocRescanLine $ix : $msg"
  721.     }
  722. }
  723. proc Ftoc_NextImplied { {show show} {implied implied} } {
  724.     global ftoc
  725.     if {$ftoc(implied) && $ftoc(direction) == "prev"} {
  726.     Ftoc_Prev $show
  727.     } else {
  728.     Ftoc_Next $show $implied
  729.     }
  730. }
  731. proc Ftoc_Next { show {implied no} } {
  732.     # Go to the next message in the scan display
  733.     global exmh flist ftoc
  734.  
  735.     set ftoc(direction) "next"
  736.     if {$ftoc(curLine) == {}} {
  737.     if [Msg_ShowUnseen] {
  738.         return
  739.     }
  740.     }
  741.     set next [FtocSkipMarked $ftoc(curLine) 1]
  742.     if {($ftoc(curLine) == $next) || \
  743.     ($ftoc(curLine) >= $ftoc(numMsgs)) || \
  744.     ($ftoc(curLine) <= 0)} {
  745.     # End of folder
  746.     Ftoc_NextFolder $implied
  747.     } else {
  748.     # Simple case - go to the next message.
  749.     Msg_Pick $next $show
  750.     }
  751. }
  752. proc Ftoc_Prev { {show show} } {
  753.     global ftoc
  754.  
  755.     Exmh_Debug Ftoc_Prev
  756.     if {$ftoc(curLine) == {}} {
  757.     if {$ftoc(numMsgs) > 0} {
  758.         Msg_Pick $ftoc(numMsgs) $show
  759.     }
  760.     return
  761.     }
  762.     if {$ftoc(curLine) > 1} then {
  763.     set ftoc(direction) "prev"
  764.     Msg_Pick [FtocSkipMarked $ftoc(curLine) -1] $show
  765.     } else {
  766.     Ftoc_Next $show implied
  767.     }
  768. }
  769. proc Ftoc_NextFolder { {implied no} } {
  770.     global ftoc exmh
  771.     # Try to chain to the next folder with unread messages.
  772.     if {$implied != "no"} {
  773.     # Implied - chained with some other operation - be lenient
  774.     if {$ftoc(changed) > 0} {
  775.         # Dirty folder - do not change.
  776.         # If on last message, clear display because the
  777.         # message is moved or deleted
  778.         if {$ftoc(curLine) != {}} {
  779.         Ftoc_ClearCurrent
  780.         Msg_ClearCurrent
  781.         }
  782.         Exmh_Status ""
  783.         Exmh_Status "Changes pending; End of folder" warn
  784.         return
  785.     }
  786.     }
  787.     set f [Flist_NextUnseen]
  788.     if {[string length $f] != 0} {
  789.     if {$ftoc(softChange)} {
  790.         set ftoc(lastFolder) $exmh(folder)
  791.         Folder_Change $f Msg_ShowUnseen
  792.         return
  793.     } else {
  794.         set ftoc(softChange) 1
  795.         Ftoc_ClearCurrent
  796.         Msg_ClearCurrent
  797.         Exmh_Status ""
  798.         Exmh_Status "End of folder; <Next> => $f" warn
  799.         return
  800.     }
  801.     }
  802.     Exmh_Status ""
  803.     Exmh_Status "End of folder" warn
  804. }
  805. proc Ftoc_LastFolder {} {
  806.     global ftoc
  807.     if {[info exist ftoc(lastFolder)]} {
  808.     return $ftoc(lastFolder)
  809.     } else {
  810.     return ""
  811.     }
  812. }
  813. proc Ftoc_PrevMarked { {show show} } {
  814.     global ftoc
  815.     set skip $ftoc(skipMarked)
  816.     set ftoc(skipMarked) 0
  817.     Ftoc_Prev $show
  818.     set ftoc(skipMarked) $skip
  819. }
  820. proc Ftoc_Marked { id } {
  821.     global ftoc exwin
  822.     if {$ftoc(skipMarked) == 0} {
  823.     return 0    ;# Pretend it isn't marked
  824.     }
  825.     set i [Ftoc_FindMsg $id]
  826.     if {[string length $i] == 0} {
  827.     return 1    ;# Can't find it, pretend it's marked
  828.     }
  829.     set marked 0
  830.     foreach tag [$exwin(ftext) tag names $i.0] {
  831.     if [regexp {(deleted|moved|drange|mrange)} $tag] {
  832.         set marked 1 ; break;
  833.     }
  834.     }
  835.     return $marked
  836. }
  837. proc FtocSkipMarked {start inc} {
  838.     global exwin ftoc
  839.  
  840.     if {$start == {}} {
  841.     return {}
  842.     }
  843.     for {set i [expr $start+$inc]} {$i > 0 && $i <= $ftoc(numMsgs)} {incr i $inc} {
  844.     if {$ftoc(skipMarked) == 0} {
  845.         return $i
  846.     }
  847.     set marked 0
  848.     foreach tag [$exwin(ftext) tag names $i.0] {
  849.         if [regexp {(deleted|moved|drange|mrange)} $tag] {
  850.         set marked 1 ; break;
  851.         }
  852.     }
  853.     if {! $marked} {
  854.         return $i
  855.     }
  856.     }
  857.     return $start
  858. }
  859.  
  860. proc Ftoc_Changes {type {allowAuto 1} } {
  861.     global ftoc
  862.  
  863.     if {$ftoc(changed) != 0} then {
  864.     Exmh_Debug Ftoc_Changes $type
  865.     if {("$allowAuto" == "1") && $ftoc(autoCommit)} {
  866.         Folder_CommitType $type
  867.         return 0
  868.     }
  869.     if {$type != {}} {
  870.         if {[string compare $type iconified] == 0} {
  871.         set msg "$ftoc(changed) changes pending"
  872.         } else {
  873.         if {$ftoc(commitDialog) &&
  874.             [FtocDialog $ftoc(changed) $type]} {
  875.             Folder_CommitType $type
  876.             Exmh_Focus
  877.             return 0
  878.         } else {
  879.             set msg "$ftoc(changed) changes pending: $type cancelled"
  880.         }
  881.         }
  882.         Exmh_Focus
  883.         Exmh_Status $msg warn
  884.         Sound_Error
  885.     } else {
  886.         Exmh_Status "Oops, $ftoc(changed) left over changes" error
  887.         set ftoc(changed) 0
  888.         return 1
  889.     }
  890.     } else {
  891.     Msg_CheckPoint        ;# Sync unseen and cur message state.
  892.     }
  893.     return $ftoc(changed)
  894. }
  895. proc FtocDialog { changes type } {
  896.     global exwin ftoc
  897.     if [winfo exists $exwin(mtext).commit] {
  898.     destroy $exwin(mtext).commit
  899.     }
  900.     set f [frame $exwin(mtext).commit -class Dialog -bd 4 -relief ridge]
  901.     set blurb [expr {($changes > 1) ? "are $changes changes" : "is one change"}]
  902.     Widget_Message $f msg -text \
  903. "There $blurb pending.
  904. (Press Return to Commit)
  905. (Press <Control-c> to Cancel)" -aspect 1000
  906.     set but [Widget_Frame $f but Dialog {top expand fill} -bd 10]
  907.     set ftoc(okToCommit) 0
  908.     Widget_AddBut $but cancel "Cancel" {set ftoc(okToCommit) 0}
  909.     Widget_AddBut $but ok "Commit and $type" {set ftoc(okToCommit) 1}
  910.     focus $but
  911.     bind $but <Return> "$but.ok flash ; $but.ok invoke"
  912.     bind $but <KP_Enter> "$but.ok flash ; $but.ok invoke"
  913.     bind $but <Control-c> "$but.cancel flash ; $but.cancel invoke"
  914.     Widget_PlaceDialog $exwin(mtext) $exwin(mtext).commit
  915.     Visibility_Wait $but
  916.     catch {grab $but}
  917.     tkwait variable ftoc(okToCommit)
  918.     catch {grab release $but}
  919.     destroy $exwin(mtext).commit
  920.     return $ftoc(okToCommit)
  921. }
  922.  
  923. proc Ftoc_Iterate { lineVar body } {
  924.     global ftoc
  925.     upvar $lineVar line
  926.     catch {
  927.     if {$ftoc(pickone)} {
  928.         if {$ftoc(curLine) != {}} {
  929.         set line $ftoc(curLine)
  930.         uplevel 1 $body
  931.         }
  932.     } else {
  933.         foreach line $ftoc(lineset) {
  934.         uplevel 1 $body
  935.         }
  936.     }
  937.     }
  938. }
  939. proc Ftoc_Unmark {} {
  940.     global ftoc
  941.  
  942.     set hits 0
  943.     Ftoc_Iterate line {
  944.     if [FtocUnmarkInner $line] { incr hits }
  945.     }
  946.     Exmh_Status "Unmarked $hits msgs"
  947.     incr ftoc(changed) -$hits
  948. }
  949. proc FtocUnmarkInner { line {all 0}} {
  950.     global exwin
  951.     set res 0
  952.     if {$all} {
  953.     set pat (deleted|moved|drange|mrange|copied)
  954.     } else {
  955.     set pat (deleted|moved|drange|mrange)
  956.     }
  957.     foreach tag [$exwin(ftext) tag names $line.0] {
  958.     if [regexp $pat $tag] {
  959.         $exwin(ftext) tag remove $tag $line.0 $line.end
  960.         if [regexp {(drange|mrange|crange)} $tag] {
  961.         eval $exwin(ftext) tag add range $line.0 $line.end
  962.         }
  963.         set res 1
  964.     }
  965.     }
  966.     return $res
  967. }
  968. proc Ftoc_Delete { line msgid } {
  969.     global exwin ftoc
  970.     $exwin(ftext) configure -state normal
  971.     $exwin(ftext) delete $line.0 "$line.end + 1 chars"
  972.     $exwin(ftext) configure -state disabled
  973.     set ftoc(displayDirty) 1
  974. }
  975. proc Ftoc_RemoveMark { line msgid } {
  976.     # Flag the current message(s) for deletion
  977.     global ftoc exwin
  978.     if ![FtocUnmarkInner $line 1] {
  979.     incr ftoc(changed)
  980.     }
  981.  
  982.     if {$ftoc(pickone)} {
  983.     $exwin(ftext) tag add deleted $line.0 $line.end
  984.     } else {
  985.     $exwin(ftext) tag remove range $line.0 $line.end
  986.     $exwin(ftext) tag add drange $line.0 $line.end
  987.     }
  988. }
  989. proc Ftoc_MoveMark { line msgid } {
  990.     global ftoc exwin exmh
  991.     if ![FtocUnmarkInner $line] {
  992.     incr ftoc(changed)
  993.     }
  994.     # This tag records the target folder
  995.     $exwin(ftext) tag add [list moved $exmh(target)] $line.0 $line.end
  996.  
  997.     if {$ftoc(pickone)} {
  998.     $exwin(ftext) tag add moved $line.0 $line.end
  999.     } else {
  1000.     $exwin(ftext) tag remove range $line.0 $line.end
  1001.     $exwin(ftext) tag add mrange $line.0 $line.end
  1002.     }
  1003. }
  1004. proc Ftoc_CopyMark { line msgid } {
  1005.     global ftoc exwin exmh
  1006.     if ![FtocUnmarkInner $line] {
  1007.     incr ftoc(changed)
  1008.     }
  1009.     # This tag records the target folder
  1010.     $exwin(ftext) tag add [list copied $exmh(target)] $line.0 $line.end
  1011.  
  1012.     if {$ftoc(pickone)} {
  1013.     $exwin(ftext) tag add moved $line.0 $line.end
  1014.     } else {
  1015.     $exwin(ftext) tag remove range $line.0 $line.end
  1016.     $exwin(ftext) tag add mrange $line.0 $line.end
  1017.     }
  1018. }
  1019. proc Ftoc_Commit { rmmCommit moveCommit copyCommit } {
  1020.     global ftoc exwin
  1021.  
  1022.     # Disable operations on ranges
  1023.     Ftoc_RangeUnHighlight
  1024.     if {! $ftoc(pickone)} {
  1025.     Buttons_Range 0
  1026.     set ftoc(lineset) {}
  1027.     set ftoc(pickone) 1
  1028.     }
  1029.  
  1030.     Exmh_Status "Committing $ftoc(changed) changes..."
  1031.     $exwin(ftext) configure -state normal
  1032.     FtocCommit deleted $rmmCommit
  1033.     FtocCommit moved $moveCommit $copyCommit
  1034.     $exwin(ftext) configure -state disabled
  1035.     set l $ftoc(curLine)
  1036.     if {$l == {}} {
  1037.     set l $ftoc(numMsgs)
  1038.     }
  1039.     if {$l > 0} {
  1040.     WidgetTextYview $exwin(ftext) $l
  1041.     }
  1042.     if {! [Ftoc_Changes {} noautocommit]} {
  1043.     Exmh_Status "ok"
  1044.     }
  1045. }
  1046. proc FtocCommit {tagname commitProc {copyCommitProc {}} } {
  1047.     global ftoc exmh exwin msg
  1048.  
  1049.     set delmsgs {}
  1050.     set curid [file tail $msg(path)]
  1051.     set pairs [FtocMakeReversePairs [$exwin(ftext) tag ranges $tagname]]
  1052.     foreach range $pairs {
  1053.     set c0 [lindex $range 0]
  1054.     set ce [lindex $range 1]
  1055.     scan $c0 "%d" L
  1056.     set msgid [Ftoc_MsgNumber $L]
  1057.     set F {}
  1058.     set delline 0    ;# Nuke display line
  1059.     foreach tag [$exwin(ftext) tag names $c0] {
  1060.         if {([llength $tag] == 2) && ([lindex $tag 0] == "moved")} {
  1061.         set F [lindex $tag 1]
  1062.         # Build up a list of moved messages
  1063.         # Note that the original order of the messages is maintained,
  1064.         # (We are going from bottom to top thru the display.)
  1065.         # The scan lines are reversed, which is handled by Scan_Move.
  1066.         if ![info exists movemsgs($F)] {
  1067.             set movemsgs($F) $msgid
  1068.         } else {
  1069.             set movemsgs($F) [concat $msgid " " $movemsgs($F)]
  1070.         }
  1071.         lappend movescan($F) [$exwin(ftext) get $c0 "$ce + 1 chars"]
  1072.         set delline 1
  1073.         }
  1074.         if {([llength $tag] == 2) && ([lindex $tag 0] == "copied")} {
  1075.         set F [lindex $tag 1]
  1076.         # Build up a list of moved messages
  1077.         # Note that the original order of the messages is maintained,
  1078.         # (We are going from bottom to top thru the display.)
  1079.         # The scan lines are reversed, which is handled by Scan_Move.
  1080.         if ![info exists copymsgs($F)] {
  1081.             set copymsgs($F) $msgid
  1082.         } else {
  1083.             set copymsgs($F) [concat $msgid " " $copymsgs($F)]
  1084.         }
  1085.         lappend movescan($F) [$exwin(ftext) get $c0 "$ce + 1 chars"]
  1086.         }
  1087.     }
  1088.     if {$tagname == "deleted"} {
  1089.         # Batch up deletes
  1090.         lappend delmsgs $msgid
  1091.         set delline 1
  1092.     }
  1093.     Flist_MsgSeen $msgid    ;# in case deleted or moved w/out viewing
  1094.     if {$delline} {
  1095.         Msg_UnSeen $msgid    ;# avoid MH mark bug
  1096.         $exwin(ftext) delete $c0 "$ce + 1 chars"
  1097.         set ftoc(displayDirty) 1
  1098.         if {$msgid == $curid} {
  1099.         Ftoc_ClearCurrent
  1100.         Msg_ClearCurrent
  1101.         }
  1102.         if {$L == $ftoc(curLine)} {
  1103.         set ftoc(curLine) {}
  1104.         } elseif {$ftoc(curLine) != {}} {
  1105.         if {$L < $ftoc(curLine)} {
  1106.             incr ftoc(curLine) -1
  1107.             if {$ftoc(curLine) == 0} {
  1108.             set ftoc(curLine) {}
  1109.             }
  1110.         }
  1111.         }
  1112.         incr ftoc(numMsgs) -1
  1113.     } else {
  1114.         FtocUnmarkInner $L
  1115.     }
  1116.     incr ftoc(changed) -1
  1117.     }
  1118.     if {$delmsgs != {}} {
  1119.     Exmh_Status "$commitProc $delmsgs"
  1120.     if [catch {
  1121.         BgAction "Rmm $exmh(folder)" $commitProc $exmh(folder) $delmsgs
  1122.     } err] {
  1123.         Exmh_Status $err error
  1124.     }
  1125.     }
  1126.     # Do copies before links so you can both move and copy a message.
  1127.     if {[catch {array names copymsgs} flist] == 0} {
  1128.     foreach f $flist {
  1129.         Exmh_Status "Copying to $f, $copymsgs($f)"
  1130.         if [catch {
  1131.         BgAction "Refile $f" $copyCommitProc $exmh(folder) $copymsgs($f) $f
  1132.         } err] {
  1133.         Exmh_Status $err error
  1134.         }
  1135.     }
  1136.     }
  1137.     if {[catch {array names movemsgs} flist] == 0} {
  1138.     foreach f $flist {
  1139.         Exmh_Status "Refiling to $f, $movemsgs($f)"
  1140.         if [catch {
  1141.         BgAction "Refile $f" $commitProc $exmh(folder) $movemsgs($f) $f
  1142.         } err] {
  1143.         Exmh_Status $err error
  1144.         }
  1145.     }
  1146.     }
  1147. }
  1148. proc FtocMakePairs { list } {
  1149.     set result {}
  1150.     for {set i 0} {$i < [expr [llength $list]-1]} {incr i +2} {
  1151.     set first [lindex $list $i]
  1152.     set second [lindex $list [expr $i+1]]
  1153.     lappend result [list $first $second]
  1154.     }
  1155.     if {$result == {}} {
  1156.     return $list
  1157.     } else {
  1158.     return $result
  1159.     }
  1160. }
  1161. proc FtocMakeReversePairs { list } {
  1162.     set result {}
  1163.     for {set i [expr [llength $list]-1]} {$i >= 0} {incr i -2} {
  1164.     set second [lindex $list $i]
  1165.     set first [lindex $list [expr $i-1]]
  1166.     lappend result [list $first $second]
  1167.     }
  1168.     if {$result == {}} {
  1169.     return $list
  1170.     } else {
  1171.     return $result
  1172.     }
  1173. }
  1174.  
  1175. proc Ftoc_MoveFeedback { msgid line } {
  1176.     global exwin ftoc
  1177.     set msg [Exmh_OldStatus]
  1178.     if {[string compare $line "last"] == 0} {
  1179.     set line $ftoc(numMsgs)
  1180.     } elseif {[string compare $line first] == 0} {
  1181.     set line 1
  1182.     }
  1183.     foreach tag [$exwin(ftext) tag names $line.0] {
  1184.     if [regexp {moved (.+)} $tag match folder] {
  1185.         Exmh_Status "$msgid => +$folder"
  1186.         return
  1187.     } elseif [regexp deleted $tag] {
  1188.         Exmh_Status "$msgid Pending Delete"
  1189.         return
  1190.     }
  1191.     }
  1192.     Exmh_Status $msg
  1193. }
  1194. proc Ftoc_FindNext {} {
  1195.     Find_It forw
  1196. }
  1197. proc Ftoc_FindPrev {} {
  1198.     Find_It back
  1199. }
  1200. proc Ftoc_FindAll {string} {
  1201.     global exwin find ftoc
  1202.     if {[string length $string] == 0} {
  1203.     Exmh_Status "No search string" warn
  1204.     return -1
  1205.     }
  1206.     set msgids {}
  1207.     for {set L 1} 1 {incr L} {
  1208.     if [$exwin(ftext) compare $L.end >= end] {
  1209.         break
  1210.     }
  1211.     if [catch {$exwin(ftext) get $L.0 $L.end} text] {
  1212.         break
  1213.     }
  1214.     if [regexp -nocase -- $string $text] {
  1215.         lappend msgids [Ftoc_MsgNumberRaw $text]
  1216.     }
  1217.     }
  1218.     if {[llength $msgids] == 0} {
  1219.     Exmh_Status "No match" warn
  1220.     return 0
  1221.     } else {
  1222.     Ftoc_PickMsgs $msgids 0
  1223.     return 1
  1224.     }
  1225.  
  1226. }
  1227. proc Ftoc_FindMatch {L string} {
  1228.     global exwin ftoc
  1229.     if {$L == $ftoc(lasthit)} {
  1230.     return 0
  1231.     }
  1232.     if [catch {$exwin(ftext) get $L.0 $L.end} text] {
  1233.     return -1    ;# off the end or beginning
  1234.     }
  1235.     if [regexp -nocase -- $string $text] {
  1236.     set ftoc(lasthit) $L
  1237.     Msg_Pick $L show
  1238.     return 1
  1239.     }
  1240.     return 0
  1241. }
  1242. proc Ftoc_Yview {args} {
  1243.     global exwin
  1244.     eval {WidgetTextYview $exwin(ftext)} $args
  1245. }
  1246. proc Ftoc_Advance { advance } {
  1247.     global ftoc
  1248.     if {[string compare $advance "advance?"] == 0} {
  1249.     return $ftoc(linkAdvance)
  1250.     } else {
  1251.     return $advance
  1252.     }
  1253. }
  1254. proc Ftoc_PageUp {} {
  1255.     global exwin
  1256.     Widget_TextPageUp $exwin(ftext)
  1257. }
  1258. proc Ftoc_PageDown {} {
  1259.     global exwin
  1260.     Widget_TextPageDown $exwin(ftext)
  1261. }
  1262.  
  1263. proc Ftoc_Sort {} {
  1264.     global ftoc
  1265.     case $ftoc(autoSortType) {
  1266.     {date} { Folder_Sort -datefield date }
  1267.     {subject} { Folder_Sort -textfield subject }
  1268.     {sender} { Folder_Sort -textfield from }
  1269.     {custom} { eval Folder_Sort $ftoc(autoSortCrit) }
  1270.     }
  1271. }
  1272. proc Ftoc_SelectAll {} {
  1273.     global ftoc
  1274.     FtocRangeStart 1
  1275.     FtocRangeEnd $ftoc(numMsgs)
  1276. }
  1277. proc Ftoc_SelectAllToEnd {} {
  1278.     global ftoc
  1279.     if {$ftoc(curLine) != {}} {
  1280.       FtocRangeStart $ftoc(curLine)
  1281.     } else {
  1282.       if {$ftoc(direction) == "next"} {
  1283.         FtocRangeStart 1
  1284.       } else {
  1285.         FtocRangeStart $ftoc(numMsgs)
  1286.       }
  1287.     }
  1288.     if {$ftoc(direction) == "next"} {
  1289.       FtocRangeEnd $ftoc(numMsgs)
  1290.     } else {
  1291.       FtocRangeEnd 1
  1292.     }
  1293. }
  1294. proc Ftoc_CatchUp {} {
  1295.     global ftoc
  1296.     Ftoc_SelectAll
  1297.     Msg_Remove
  1298.     Folder_Commit
  1299.     Msg_PageOrNext
  1300. }
  1301. proc Ftoc_CatchUpToEnd {} {
  1302.     global ftoc
  1303.     Ftoc_SelectAllToEnd
  1304.     Msg_Remove
  1305.     Folder_Commit
  1306.     Msg_PageOrNext
  1307. }
  1308. #
  1309. # Interface to Drag & Drop
  1310. #
  1311. set ftocDrag(types) {foldermsg}
  1312. set ftocDrag(formats) {string filename}
  1313. set ftocDrag(format,foldermsg) string
  1314. set ftocDrag(format,filename) string
  1315. set ftocDrag(type,string) foldermsg
  1316.  
  1317. # Drag Selected
  1318. proc FtocDragSelectOld {w x y wx wy} {
  1319.     global exmh ftoc
  1320.  
  1321.         set folder $ftoc(folder)
  1322.         if !$ftoc(displayValid) {
  1323.             set folder $exmh(folder)
  1324.         }
  1325.     set line [lindex [split [$w index current] .] 0]
  1326.     set msg [Ftoc_MsgNumber $line]
  1327.     if {$msg == {} || $msg == 0} return
  1328.  
  1329.     # Hand off to Drag code
  1330.     global ftocDrag mhProfile
  1331.     set ftocDrag(source) $w
  1332.     set ftocDrag(data,foldermsg) "+$folder $msg"
  1333.     set ftocDrag(data,filename) $mhProfile(path)/$folder/$msg
  1334.     Drag_Source ftocDrag $x $y
  1335. }
  1336. proc FtocDragSelect {w x y wx wy} {
  1337.     global exmh ftoc ftocDrag mhProfile
  1338.  
  1339.     set folder $ftoc(folder)
  1340.     if !$ftoc(displayValid) {
  1341.         set folder $exmh(folder)
  1342.     }
  1343.     set msgs {}
  1344.     if $ftoc(pickone) {
  1345.     set line [lindex [split [$w index current] .] 0]
  1346.     set msgs [Ftoc_MsgNumber $line]
  1347.     if {$msgs == {} || $msgs == 0} return
  1348.     set ftocDrag(data,filename) $mhProfile(path)/$folder/$msgs
  1349.     } else {
  1350.     foreach line $ftoc(lineset) {
  1351.         set msgid [Ftoc_MsgNumber $line]
  1352.         if {$msgid != {}} {
  1353.         lappend msgs $msgid
  1354.         }
  1355.     }
  1356.         catch {unset ftocDrag(data,filename)}
  1357.     }
  1358.  
  1359.     # Hand off to Drag code
  1360.     set ftocDrag(source) $w
  1361.     set ftocDrag(data,foldermsg) "+$folder $msgs"
  1362.     Drag_Source ftocDrag $x $y
  1363.   }
  1364.  
  1365.